ASP程序代碼執(zhí)行時間統(tǒng)計類_ASP教程

教程Tag：暫無Tag,歡迎添加,賺取U幣!

推薦：代碼指導(dǎo)用ASP木馬實現(xiàn)FTP和解壓縮
我想大家都有一些開了80端口的肉雞吧，如果是國內(nèi)的出于安全就不要往下看了，如果不不妨往下看一下，小弟獻丑了，以求拋磚引玉。在肉雞上放網(wǎng)站最麻煩的可能就是更新和上傳大量的文件了，終

第一次寫ASP類，實現(xiàn)功能：分段統(tǒng)計程序執(zhí)行時間，輸出統(tǒng)計表等。

程序代碼：

以下為引用的內(nèi)容：

Class ccClsProcessTimeRecorder
''ASP程序代碼執(zhí)行時間統(tǒng)計類

Private ccInti,ccIntNonceTime,ccIntDecimal
Private ccIntStartTime,ccIntEndTime,ccIntNow,ccIntNonce
Private ccStrInterval,ccStrEvent,ccStrTime,ccStrStatisticLog,ccStrFormatInterval
Private ccArrEvent,ccArrTime

Private Sub Class_Initialize
ccStrInterval = "|" ''默認(rèn)分隔符
ccIntDecimal = 4 ''小數(shù)點后位數(shù)
ccStrEvent = ""
ccStrTime = ""
ccStrFormatInterval = "<br />" & vbCrLf
ccIntStartTime = Timer
ccIntNow = ccIntStartTime
ccIntNonce = ccIntStartTime
End Sub

Public Sub Record(ccStrEventName)
ccStrEvent = ccStrEvent & ccStrInterval & Replace(ccStrEventName,ccStrInterval,"")
ccStrTime = ccStrTime & ccStrInterval & FormatNumber(Timer-ccIntNow,ccIntDecimal,True,False,True)
ccIntNow = Timer
End Sub

Public Property Let Format(ccStrFormatType)
If LCase(Trim(ccStrFormatType)) = "html" Then
ccStrFormatInterval = "<br />" & vbCrLf
Else
ccStrFormatInterval = vbCrLf
End If
End Property

Public Function Statistic
If InStr(ccStrEvent,ccStrInterval) > 0 Then
ccIntEndTime = Timer
ccArrEvent = Split(ccStrEvent,ccStrInterval)
ccArrTime = Split(ccStrTime,ccStrInterval)
ccStrStatisticLog = ccStrStatisticLog & "Process Time Record" & ccStrFormatInterval
ccStrStatisticLog = ccStrStatisticLog & "--------------------------------------" & ccStrFormatInterval
For ccInti = 1 To UBound(ccArrEvent)
ccStrStatisticLog = ccStrStatisticLog & ccArrEvent(ccInti) & " : " & ccArrTime(ccInti) & " s" & ccStrFormatInterval
Next
ccStrStatisticLog = ccStrStatisticLog & "--------------------------------------" & ccStrFormatInterval
ccStrStatisticLog = ccStrStatisticLog & "Total : " & FormatNumber(ccIntEndTime-ccIntStartTime,ccIntDecimal,True,False,True) & " s"
Statistic = ccStrStatisticLog
Else
Statistic = "No Record"
End If
End Function

Public Function Nonce
ccIntNonceTime = FormatNumber(Timer-ccIntNonce,ccIntDecimal,True,False,True)
ccIntNonce = Timer
Nonce = ccIntNonceTime
End Function

Public Function Total
Total = FormatNumber(Timer-ccIntStartTime,ccIntDecimal,True,False,True)
End Function

End Class

類屬性：

1、Format

輸出時是否帶HTML換行標(biāo)簽

-html:輸出HTML換行標(biāo)簽和文本換行符(默認(rèn))

-text:僅輸出文本換行符

類方法：

1、Record("Code Name")

統(tǒng)計自上一次調(diào)用Record方法至現(xiàn)在的時間(第一次調(diào)用時統(tǒng)計聲明類時至調(diào)用時時間)，最后在Statistic中輸出類函數(shù)：(即時返回信息)

1、Nonce

輸出自上一次調(diào)用nonce函數(shù)至現(xiàn)在的時間(第一次調(diào)用時統(tǒng)計聲明類時至調(diào)用時時間)

2、Total

輸出聲明類到現(xiàn)在總時間

3、Statistic

輸出所有Record統(tǒng)計信息和總程序時間

實例代碼：

以下為引用的內(nèi)容：

Dim objRecord,i,k,j,x

Set objRecord = New ccClsProcessTimeRecorder
objRecord.Format = "html"

For i = 1 To 100000
x = 2 2
Next

Call objRecord.Record("加法")
For j = 1 To 100000
x = 2 * 2
Next

Call objRecord.Record("乘法")

For k = 1 To 100000
x = 2 ^ 2
Next

Call objRecord.Record("開方")

Response.Write objRecord.Statistic

輸出：

Process Time Record
--------------------------------------

加法 : 0.0625 s

乘法 : 0.0469 s

開方 : 0.1094 s

分享：如何讓你的ASP運行于非Windows平臺
自從Micorsoft推出ASP技術(shù)后，由于ASP在創(chuàng)建動態(tài)交互式站點上的強大功能及其代碼編寫的簡便性，使ASP在越來越多的Internet/Intranet/Extranet網(wǎng)站上得到了極其廣泛的應(yīng)用，尤其是涉及到數(shù)據(jù)庫操